1.8 守恒量

系统状态的函数在解路径上保持恒定的量称为守恒量或运动常数。如果 C 是一个守恒量，那么

对于解路径 q 成立。沿用历史惯例，我们也称运动常数为运动积分。79 在本节中，我们将研究具有对称性的系统，并发现对称性与守恒量相关联。例如，具有平移对称性的系统中线性动量守恒，具有旋转对称性时角动量守恒，若系统不依赖于时间原点则能量守恒。我们首先考虑可以选择坐标系自然地表达对称性的系统，随后讨论无法选择同时表达所有对称性的坐标系的情况。

1.8.1 守恒动量

如果拉格朗日量 L(t, q, v) 不依赖于某个特定的坐标 qi，那么

并且拉格朗日方程的第 i 个分量为

这等价于80

因此我们看到

是一个守恒量。函数 称为动量状态函数。动量状态函数的值即为广义动量。我们将广义动量的第 i 个分量称为共轭于第 ith 坐标的动量。81 未在拉格朗日量中显式出现的广义坐标分量称为循环坐标。共轭于任何循环坐标的广义动量分量是运动常数。其值沿可实现的路径是恒定的；但不同路径上可能取不同的值。正如我们将看到的，即使动量不守恒，它也是一个重要的量。

给定坐标路径 q 和拉格朗日量 L，动量路径 p 为

其分量为

动量路径对任意路径 q 都有良好定义。如果路径是可实现的且拉格朗日量不依赖于 qi，那么 pi 是一个常数函数

pi 的常数值在不同轨迹上可能不同。

守恒动量的例子

自由粒子拉格朗日量 L(t, x, v) = (1/2) mv2 不依赖于 x。因此动量状态函数 (t, q, v) = mv 沿可实现路径守恒。坐标路径 q 对应的动量路径 p 为 p(t) = o [q](t) = m Dq(t)。对于可实现路径，Dp(t) = 0。对于自由粒子，通常的线性动量沿可实现路径守恒。

对于中心力场中的粒子（第1.6节），拉格朗日量

依赖于 r，但不依赖于 。动量状态函数为

它有两个分量。第一个分量，即“径向动量”，不守恒。第二个分量，即“角动量”，沿任何解轨迹守恒。

如果中心势问题是用直角坐标表达的，那么所有坐标都会出现在拉格朗日量中。在这种情况下，将不存在任何明显的守恒量。然而，系统的运动不依赖于坐标的选择，因此角动量仍然守恒。

我们看到，明智地选择坐标系有很大的优势。如果我们能选择坐标使得系统的对称性反映为拉格朗日量中缺少某个坐标分量，那么相应的守恒量将自动存在。82

1.8.2 能量守恒

如果拉格朗日量不依赖于相应的坐标，则动量由运动所守恒。如果拉格朗日量 L(t, q, ) 不显式依赖于时间：0 L = 0，则存在另一个运动常数，即能量。

考虑沿解路径 q 的拉格朗日量的时间导数：

利用拉格朗日方程改写第二项，得到

分离出 0 L 并将右侧前两项合并，得到

其中，如前所述， 从状态中选出速度。因此我们看到，如果 0 L = 0，那么

沿可实现路径守恒。函数 称为能量状态函数。83 记 E = o [q] 为路径 q 上的能量函数。如果拉格朗日量没有显式时间依赖性，能量函数沿任何可实现轨迹具有常数值；能量 E 在不同轨迹上可能取不同的值。没有显式时间依赖性的系统称为自治系统。

给定拉格朗日量过程 L，我们可以计算能量：

(define (Lagrangian->energy L)
  (let ((P ((partial 2) L)))
    (- (* P velocity) L)))

用动能和势能表示的能量

在某些情况下，能量可以写为动能与势能之和。假设系统由直角坐标为 x 的粒子组成，其运动可能受到约束，并且这些直角坐标是广义坐标 q 以及可能的时间 t 的某些函数：x = f(t, q)。我们构建拉格朗日量为 L = T - V，并通过用广义速度表达直角速度来计算以 q 表示的动能：

动能为

其中 v 是 v 的大小。

如果 f 函数不显式依赖于时间（0 f = 0），那么直角速度是广义速度的齐次函数（次数为1），而 T 是广义速度的齐次函数（次数为2），因为它由次数为1的齐次函数的平方求和构成。如果 T 是广义速度的二次齐次函数，那么

其中第二个等式由欧拉齐次函数定理得出。84 能量状态函数为

因此，如果 f 不依赖于时间，能量函数可改写为

注意，如果 V 依赖于时间，能量仍然是动能与势能之和，但能量不守恒。

能量状态函数始终是定义良好的函数，无论它是否能写成 T + V 的形式，也无论它是否沿可实现路径守恒。

练习1.28. 当 f 显式依赖于时间时，有一个类似的结果成立。

a. 证明在这种情况下动能包含与广义速度成线性关系的项。

b. 证明，通过添加一个全时间导数，拉格朗日量可以写成 L = A - B 的形式，其中 A 是广义速度的齐次二次型，B 与速度无关。

c. 利用欧拉定理证明能量函数为 = A + B。

之前已经给出了一个通过添加全时间导数从拉格朗日量中移除速度线性项的例子：受驱动的摆。

练习1.29. 质量为 m 的粒子在均匀引力场（加速度为 g）中从半径为 R 的水平圆柱上滑落。如果粒子从靠近圆柱顶部以零初速度开始，它以多大的角速度离开圆柱？

1.8.3 三维中心力

一个重要的物理系统是粒子在三维空间中心场中的运动，势能 V(r) 任意且仅依赖于半径。我们将在球坐标 r、 和 中描述该系统，其中 是余纬度， 是经度。动能包含三项：

用过程表示为：

(define ((T3-spherical m) state)
  (let ((q (coordinate state))
        (qdot (velocity state)))
    (let ((r (ref q 0))
          (theta (ref q 1))
          (rdot (ref qdot 0))
          (thetadot (ref qdot 1))
          (phidot (ref qdot 2)))
      (* 1/2 m
         (+ (square rdot)
            (square (* r thetadot))
            (square (* r (sin theta) phidot)))))))

然后通过减去势能形成拉格朗日量：

(define (L3-central m Vr)
  (define (Vs state)
    (let ((r (ref (coordinate state) 0)))
      (Vr r)))
  (- (T3-spherical m) Vs))

首先让我们看看广义力（拉格朗日量对广义坐标的偏导数）。我们通过对拉格朗日量的坐标参数求偏导数来计算这些量：

(show-expression
 (((partial 1) (L3-central 'm (literal-function 'V)))
  (up 't
      (up 'r 'theta 'phi)
      (up 'rdot 'thetadot 'phidot))))

方向的力分量为零，因为 不出现在拉格朗日量中（它是一个循环变量）。相应的动量分量守恒。计算动量：

(show-expression
 (((partial 2) (L3-central 'm (literal-function 'V)))
  (up 't 
      (up 'r 'theta 'phi)
      (up 'rdot 'thetadot 'phidot))))

共轭于 的动量守恒。这是角动量 × (m ) 的 z 分量，其中 是位置矢量，m 是线性动量。我们可以通过写出角动量在球坐标中的 z 分量来证明这一点：

(define ((ang-mom-z m) state)
  (let ((q (coordinate state))
        (v (velocity state)))
     (ref (cross-product q (* m v)) 2)))
(define (s->r state)
  (let ((q (coordinate state)))
    (let ((r (ref q 0))
          (theta (ref q 1))
          (phi (ref q 2)))
      (let ((x (* r (sin theta) (cos phi)))
            (y (* r (sin theta) (sin phi)))
            (z (* r (cos theta))))
        (up x y z)))))
(show-expression
  ((compose (ang-mom-z 'm) (F->C s->r))
   (up 't 
       (up 'r 'theta 'phi)
       (up 'rdot 'thetadot 'phidot))))

z 轴的选择是任意的，因此角动量任何分量的守恒都意味着所有分量的守恒。因此总角动量守恒。我们可以选择 z 轴使得所有角动量都集中在 z 分量上。角动量必须同时垂直于径向矢量和线性动量矢量。因此运动是平面的： = /2 且 = 0。中心力场中的平面运动已在第1.6节中讨论过。

我们还可以看到，从中心场的拉格朗日量计算出的能量状态函数实际上就是 T + V：

(show-expression
 ((Lagrangian->energy (L3-central 'm (literal-function 'V)))
  (up 't
      (up 'r 'theta 'phi)
      (up 'rdot 'thetadot 'phidot))))

能量守恒，因为拉格朗日量没有显式时间依赖性。

练习1.30. 受驱动球摆 球摆是一个沉重摆锤，受均匀重力作用，可在三维空间中摆动，但与支点保持固定距离。为支点做竖直运动的受驱动球摆构造拉格朗日量。你能找到什么对称性？找出能够表达该对称性的坐标。什么量守恒？给出守恒量的解析表达式。

1.8.4 诺特定理

我们已经看到，如果一个系统具有对称性，并且可以选取坐标系使得拉格朗日量不依赖于与该对称性相关联的坐标，那么就存在一个与该对称性相关联的守恒量。然而，存在更普遍的对称性，没有任何坐标系统能够完全表达它们。例如，中心势中的运动是球对称的（动力学系统绕任意轴的旋转不变），但用球坐标表达系统的拉格朗日量仅表现出绕一个轴的对称性。更一般地，如果存在一个使拉格朗日量不变的坐标变换，则该拉格朗日量具有对称性。连续对称性是一个参数化的对称性族。诺特证明了，对于任何连续对称性，都存在一个守恒量。

考虑一个参数化的坐标变换 ，参数为 s：

对应于这个参数化的坐标变换，有一个参数化的状态变换 ：

我们要求变换 (0) 是恒等坐标变换 x' = (0)(t, x')，相应地 (0) 是恒等状态变换 (t, x', v') = (0)(t, x', v')。拉格朗日量 L 具有对应于 的连续对称性，如果它在变换下不变

对任意 s 成立。拉格朗日量 L 与变换后的拉格朗日量 (s) 是同一个函数。

(s) = L 对任意 s 成立意味着 D(s) = 0。显式地，(s) 为

其中我们将 (s) 的速度分量用全时间导数重新表达。 的导数为零：

其中我们使用了这样一个事实85

在可实现路径 q 上，我们可以利用拉格朗日方程改写第一项：

当 s = 0 时，路径 q 和 q' 相同，因为 (0) 是恒等变换，所以 [q] = [q']，该方程变为

因此状态函数

沿解轨迹守恒。这就是诺特积分。该积分是动量与一个与对称性相关的矢量的乘积。

示例：中心势中的运动

例如，考虑直角坐标中的中心势拉格朗日量：

以及绕 z 轴的参数化旋转 Rz(s)

旋转是正交变换，因此

沿路径求微分，得到

因此速度也通过正交变换变换，并且 vx2 + vy2 + vz2 = (vx')2 + (vy')2 + (vz')2。因此

我们看到 L' 与 L 是完全相同的函数。

动量为

以及

因此诺特积分为

我们认出这是角动量的负 z 分量： × (m )。由于拉格朗日量在任何连续旋转对称性下保持不变，中心势问题中矢量角动量的所有分量都守恒。

过程调用 ((Rx angle-x) q)、((Ry angle-y) q) 和 ((Rz angle-z) q) 将直角元组 q 绕指定轴旋转指定角度。86 我们用它们来构造一个参数化的坐标变换 F-tilde：

(define (F-tilde angle-x angle-y angle-z)
  (compose (Rx angle-x) (Ry angle-y) (Rz angle-z) coordinate))

中心势中运动的拉格朗日量为

(define ((L-central-rectangular m U) state)
  (let ((q (coordinate state))
        (v (velocity state)))
    (- (* 1/2 m (square v)) (U (sqrt (square q))))))

诺特积分即为

(define Noether-integral
  (let ((L (L-central-rectangular 
            'm (literal-function 'U))))
    (* ((partial 2) L) ((D F-tilde) 0 0 0))))

(print-expression
  (Noether-integral 
    (up 't
        (up 'x 'y 'z)
        (up 'vx 'vy 'vz))))
(down (+ (* m vy z) (* -1 m vz y))
      (+ (* m vz x) (* -1 m vx z))
      (+ (* m vx y) (* -1 m vy x)))

我们得到角动量的所有三个分量。